Belajar Membuat EA Sederhana 33 (Proteksi EA)

Salam Profit semuanya!

Sepertinya udah banyak sih share coding EA sampai part 32.......

Nah kali ini kita akan belajar tentang proteksi EA ....karena ada bebepa temen di Ym yang minta di ajari proteksi EA ...............

Ada banyak cara untuk proteksi EA ataupun script dan Indikator al:

Proteksi Demo ==> EA hanya bisa digunakan untuk account demo.
Proteksi accout khusus ==> hanya bisa digunakan account tertentu saja.
Proteksi Broker ==> hanya bisa digunakan broker tertentu saja
Proteksi Pair ==> hanya bisaa digunakan pair tertentu saja.
Proteksi waktu ==> dibatasi sampai waktu tertentu : tgl -bulan-tahun
Proteksi Nama==>hanya bisa digunakan dengan nama account tertentu
Proteksi Pasword==> menggunakan pasword tertentu ,lisensi number
Proteksi dll ==>menggunakan file dll
Proteksi webs==> harus tersambung dengan webs
dll.

Nah kita akan bahas beberapa proteksi ..............

Yang Pertama

Proteksi account demo
Untuk memproteksi supaya EA hanya bisa digunakandi account demo disini kita tambahkan pembaca account demo yaitu: IsDemo()
Nah dari sini kita kembangkan dalam sebuah operasi

if(!IsDemo()){Alert("Maaf bos hanya untuk demo");return(0);}

Nah , if(!IsDemo()){ ini artinya bila tidak demo maka blabla.............yaitu Alert("Maaf bos hanya untuk demo") =>maka alert akan berbunyi dan memberi tahu ..............
ditambahkan untuk menghentikan perintah berikutnya yaitu return(0);

Code tersebut di tempatkan di dalam atau dibawah int start(){
contoh:

int start(){ if(!IsDemo()){Alert("Maaf bos hanya untuk demo");return(0);}

Nah untuk lebih jelasnya saya akan proteksi EA di part 21

sehingga jadinya begini

//+-----------------------------------------------------------------------------------------+
//|                                                    EA Jum+Profit |
//|                                                gifaesa@yahoo.com |
//|                                     http://JumForex.blogspot.com |
//+------------------------------------------------------------------+

#property copyright "JumForex.blogspot.com"
#property link      "Gifaesa@yahoo.com"

extern string  Nama_EA                 = "Jum+Profit";
extern bool    Trade_buystop           = true;
extern bool    Trade_sellstop          = true;
extern string  Jam_server              = "Set sesuai selera";
extern int     Jam                     = 0;
extern int     Menit                   = 30;
extern bool    Tp_in_Money             = false;
extern double  TP_in_money             = 5;
extern int     TP                      = 100;
extern int     SL                      = 20;
extern double  Lots                    = 0.1;
extern int     Jarak_stop              = 25;
extern bool    TrailingStop_           = true;
extern int     TrailingStop            = 12;
extern int     Magic                   = 69;
double slb,tpb,sls,tps,pt,lslb,ltpb;
//+------------------------------------------------------------------+
//| expert initialization function                                   |
//+------------------------------------------------------------------+
int init()
  {
//----
   if(Digits==3 || Digits==5) pt=10*Point;   else   pt=Point;
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert deinitialization function                                 |
//+------------------------------------------------------------------+
int deinit()
  {
//----

//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert start function                                            |
//+------------------------------------------------------------------+
int start()
  {
if(!IsDemo()){Alert("Maaf bos hanya untuk demo");return(0);}
label();
if(TrailingStop_)dtrailing();
if(Tp_in_Money ){
  if(TP_in_money<= money(0)){ 
   closeall(0);
   closeall(2);
   }
  if(TP_in_money<= money(1)){ 
   closeall(1);
   closeall(3);
   }
 }
if(jumlahorder(0)==1 && jumlahorder(1)==0){ 
   closeall(5);
   }
if(jumlahorder(0)==0 && jumlahorder(1)==1){ 
   closeall(4);
   }
if(Hour()==23){
   closeall(4);
   closeall(5);
   }
//----
   double as = Ask + Jarak_stop*pt;
   double bi = Bid - Jarak_stop*pt;
   if(SL==0)slb=0;else slb=as-SL*pt;
   if(SL==0)sls=0;else sls=bi+SL*pt;
   if(TP==0)tpb=0;else tpb=as+TP*pt;
   if(TP==0)tps=0;else tps=bi-TP*pt;
if(DayOfWeek()!=1 && Hour()==Jam && Minute()==Menit && jumlahorder(0)==0 && jumlahorder(1)==0){
  if(jumlahorder(4)==0  && Trade_buystop  ) {OrderSend(Symbol(),OP_BUYSTOP,NR(Lots),as,3,slb, tpb,Nama_EA,Magic,0,Blue);}
  if(jumlahorder(5)==0  && Trade_sellstop ) {OrderSend(Symbol(),OP_SELLSTOP,NR(Lots),bi,3,sls, tps,Nama_EA,Magic,0,Red);}
 }

return(0);
  }
//+------------------------------------------------------------------+

int jumlahorder( int tipe)
{
int total=0;
for(int i=0; i<OrdersTotal(); i++)
  {
      OrderSelect(i,SELECT_BY_POS,MODE_TRADES);
      if(OrderSymbol()!=Symbol() || OrderMagicNumber()!=Magic || OrderType()!=tipe) continue;
     total++;
  }

return(total);
}
double NR(double thelot)
{
    double maxlots = MarketInfo(Symbol(), MODE_MAXLOT),
    minilot = MarketInfo(Symbol(), MODE_MINLOT),
    lstep = MarketInfo(Symbol(), MODE_LOTSTEP);
    double lots = lstep * NormalizeDouble(thelot / lstep, 0);
    lots = MathMax(MathMin(maxlots, lots), minilot);
    return (lots);
}

void dtrailing()
{
for(int i=0; i<OrdersTotal(); i++){
      OrderSelect(i,SELECT_BY_POS,MODE_TRADES);
        if(OrderSymbol()!=Symbol() || OrderMagicNumber()!=Magic ) continue;
        if(OrderType()==OP_BUY)  {
         if(Bid-OrderOpenPrice()>pt*TrailingStop)  {
           if((OrderStopLoss()<Bid-pt*TrailingStop) || (OrderStopLoss()==0)) {
              OrderModify(OrderTicket(),OrderOpenPrice(),Bid-pt*TrailingStop,OrderTakeProfit(),0,Green);
              return(0);
              }
              }
           }
        if(OrderType()==OP_SELL)  {
         if((OrderOpenPrice()-Ask)>(pt*TrailingStop)){
           if(OrderStopLoss()>(Ask+pt*TrailingStop) || (OrderStopLoss()==0)){
              OrderModify(OrderTicket(),OrderOpenPrice(),Ask+pt*TrailingStop,OrderTakeProfit(),0,Red);
              return(0);
              }
              }
           }
     }
  
}
void closeall(int m)
{
 for (int i = OrdersTotal() - 1; i >= 0; i--) {
  OrderSelect(i, SELECT_BY_POS, MODE_TRADES);
  if (OrderSymbol() != Symbol() || OrderMagicNumber()!=Magic||  OrderType()!=m) continue;
   if (OrderType() > 1) OrderDelete(OrderTicket());
  if (OrderType() == 0) OrderClose(OrderTicket(), OrderLots(), Bid, 3, CLR_NONE);
  if (OrderType() == 1)OrderClose(OrderTicket(), OrderLots(), Ask, 3, CLR_NONE);
 }
}
double money(int m)
{
 double dp = 0;
 int i;
 for (i = 0; i < OrdersTotal(); i++) {
  OrderSelect(i, SELECT_BY_POS, MODE_TRADES);
  if (OrderSymbol() != Symbol()  || OrderMagicNumber()!=Magic || m!=OrderType()) continue;
  dp += OrderProfit();
 }
 return(dp);
}

void label()
{
 Comment("\n ",
   "\n ",
   "\n ------------------------------------------------",
   "\n :: =>+Jum+Profit<=",
   "\n :: =>JumForex.blogspot.com<=",
   "\n ------------------------------------------------",
   "\n :: Spread                 : ", MarketInfo(Symbol(), MODE_SPREAD),
   "\n :: Leverage               : 1 : ", AccountLeverage(),
   "\n :: Equity                 : ", AccountEquity(),
   "\n :: Jam Server             :", Hour(), ":", Minute(),
   "\n ------------------------------------------------",
   "\n :: Floting buy : ",money(0),
   "\n :: Floting sell : ",money(1),
   "\n ------------------------------------------------",
   "\n :: >>By: Jum69<<",
   "\n ------------------------------------------------");
}

Ternyata hanya dengan sebaris perintah tersebut cukup ampuh bahwasanya EA hanya akan bisa digunakan di account demo he he he..............Mudah kan?

Oke deh sementara disini dulu ya nanti kita saambung lagi di part berikutnya

------------------------------------------------------------------------------------------
Pastikan mengikuti part sebelumnya

Belajar Membuat EA sederhana Part 27

Belajar Membuat EA sederhana part 28

Belajar Membuat EA sederhana Part 29

Belajar Membuat EA sederhana Part 30

Belajar Membuat EA sederhana Part 31

Belajar Membuat EA sederhana Part 32

Belajar Membuat EA Sederhana 33

Belajar Membuat EA Sederhana 34

Belajar Membuat EA Sederhana 35