Belajar Membuat EA Sederhana 21 (Jebakan)

Pastikan sudah mengikuti di part 20 disini

Pada posting kali ini saya akan coba bahas tentang EA jebakan dengan menggunakan dua buah order pending stop.

Adapun rulenya adalah pada jam tertentu langsung pasang 2 buah order buystop dan sellstop dan ketika salah satu order pening stop tersebut tersentuh maka order pending stop yang tersisa langsung didelet.
Kemudian bila pada hari itu tidak tersentuh maka akan didelet. dan tambahan lain pada hari senin tidak trading karena EA ini cocok untuk trend pada hari itu , kalau hari senin diperkirakan biasanya sideway.

Jadi order setiap hari hanya akan melakukan order satu kali saja.

Coba perhatikan gambar di atas pada tanda panah , jadi pada jam server kira 2 jam 0 : 30 maka order stop akan di pasang .

Nah Kita coba buat deklarasinya sbb:


extern string  Nama_EA                 = "Jum+Profit";

extern bool    Trade_buystop           = true;

extern bool    Trade_sellstop          = true;

extern string  Jam_server              = "Set sesuai selera";

extern int     Jam                     = 0;

extern int     Menit                   = 30;

extern bool    Tp_in_Money             = false;

extern double  TP_in_money             = 5;

extern int     TP                      = 100;

extern int     SL                      = 20;

extern double  Lots                    = 0.1;

extern int     Jarak_stop              = 25;

extern bool    TrailingStop_           = true;

extern int     TrailingStop            = 12;

extern int     Magic                   = 69;

double slb,tpb,sls,tps,pt,lslb,ltpb;

Beberapa bagian yang saya coba siapkan adalah script delet order type, disini dibuat dalam bentuk fungsi sbb :


void closeall(int m)

{

 for (int i = OrdersTotal() - 1; i >= 0; i--) {

  OrderSelect(i, SELECT_BY_POS, MODE_TRADES);

  if (OrderSymbol() != Symbol() || OrderMagicNumber()!=Magic||  OrderType()!=m) continue;

   if (OrderType() > 1) OrderDelete(OrderTicket());

  if (OrderType() == 0) OrderClose(OrderTicket(), OrderLots(), Bid, 3, CLR_NONE);

  if (OrderType() == 1)OrderClose(OrderTicket(), OrderLots(), Ask, 3, CLR_NONE);

 }

}

Untuk menentukan order pada jam tertentu sy buat bagian sbb:


Hour()==Jam && Minute()==Menit

Untuk bagian delet ketika salah satu order stop tersenttuh adalah:


if(jumlahorder(0)==1 && jumlahorder(1)==0){ 

   closeall(5);

   }

if(jumlahorder(0)==0 && jumlahorder(1)==1){ 

   closeall(4);

   }

sedang bagian untuk mendelet orderstop yang tidak tersentuh maka pada jam tersentu di delet
contoh jam 23


if(Hour()==23){

   closeall(4);

   closeall(5);

   }

Untuk asesoris order Pending stop :


   double as = Ask + Jarak_stop*pt;

   double bi = Bid - Jarak_stop*pt;

   if(SL==0)slb=0;else slb=as-SL*pt;

   if(SL==0)sls=0;else sls=bi+SL*pt;

   if(TP==0)tpb=0;else tpb=as+TP*pt;

   if(TP==0)tps=0;else tps=bi-TP*pt;

Bagian lain untuk membuat EA libut trading hari senin adalah

DayOfWeek()!=1

Nah EA jadinya sbb

//+------------------------------------------------------------------+
//|                                                    EA Jum+Profit |
//|                                                gifaesa@yahoo.com |
//|                                     http://JumForex.blogspot.com |
//+------------------------------------------------------------------+

#property copyright "JumForex.blogspot.com"
#property link      "Gifaesa@yahoo.com"
#property version   "1.00"
#property strict

extern string  Nama_EA                 = "Jum+Profit";
extern bool    Trade_buystop           = true;
extern bool    Trade_sellstop          = true;
extern string  Jam_server              = "Set sesuai selera";
extern int     Jam                     = 0;
extern int     Menit                   = 30;
extern bool    Tp_in_Money             = false;
extern double  TP_in_money             = 5;
extern int     TP                      = 100;
extern int     SL                      = 20;
extern double  Lots                    = 0.1;
extern int     Jarak_stop              = 25;
extern bool    TrailingStop_           = true;
extern int     TrailingStop            = 12;
extern int     Magic                   = 69;
double slb,tpb,sls,tps,pt,lslb,ltpb;
int tiket;
//+------------------------------------------------------------------+
//| expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
    if(Digits==3 || Digits==5) pt=10*Point;   else   pt=Point;
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
   
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
label();
if(TrailingStop_)dtrailing();
if(Tp_in_Money ){
  if(TP_in_money<= money(0)){ 
   closeall(0);
   closeall(2);
   }
  if(TP_in_money<= money(1)){ 
   closeall(1);
   closeall(3);
   }
 }
if(jumlahorder(0)==1 && jumlahorder(1)==0){ 
   closeall(5);
   }
if(jumlahorder(0)==0 && jumlahorder(1)==1){ 
   closeall(4);
   }
if(Hour()==23){
   closeall(4);
   closeall(5);
   }
//----
   double as = Ask + Jarak_stop*pt;
   double bi = Bid - Jarak_stop*pt;
   if(SL==0)slb=0;else slb=as-SL*pt;
   if(SL==0)sls=0;else sls=bi+SL*pt;
   if(TP==0)tpb=0;else tpb=as+TP*pt;
   if(TP==0)tps=0;else tps=bi-TP*pt;
if(DayOfWeek()!=1 && Hour()==Jam && Minute()==Menit && jumlahorder(0)==0 && jumlahorder(1)==0){
  if(jumlahorder(4)==0  && Trade_buystop  ) {if(OrderSend(Symbol(),OP_BUYSTOP,NR(Lots),as,3,slb, tpb,Nama_EA,Magic,0,Blue))Print("JumForex BuyStop");}
  if(jumlahorder(5)==0  && Trade_sellstop ) {if(OrderSend(Symbol(),OP_SELLSTOP,NR(Lots),bi,3,sls, tps,Nama_EA,Magic,0,Red))Print("JumForex SellStop");}
 }
  }
//+------------------------------------------------------------------+

int jumlahorder( int tipe)
{
int total=0;
for(int i=0; i<OrdersTotal(); i++)
  {
      if(!OrderSelect(i,SELECT_BY_POS,MODE_TRADES))continue;
      if(OrderSymbol()!=Symbol() || OrderMagicNumber()!=Magic || OrderType()!=tipe) continue;
     total++;
  }

return(total);
}
double NR(double thelot)
{
    double maxlots = MarketInfo(Symbol(), MODE_MAXLOT),
    minilot = MarketInfo(Symbol(), MODE_MINLOT),
    lstep = MarketInfo(Symbol(), MODE_LOTSTEP);
    double lots = lstep * NormalizeDouble(thelot / lstep, 0);
    lots = MathMax(MathMin(maxlots, lots), minilot);
    return (lots);
}

void dtrailing()
{
for(int i=0; i<OrdersTotal(); i++){
      if(!OrderSelect(i,SELECT_BY_POS,MODE_TRADES))continue;
        if(OrderSymbol()!=Symbol() || OrderMagicNumber()!=Magic ) continue;
        if(OrderType()==OP_BUY)  {
         if(Bid-OrderOpenPrice()>pt*TrailingStop)  {
           if((OrderStopLoss()<Bid-pt*TrailingStop) || (OrderStopLoss()==0)) {
              tiket=OrderModify(OrderTicket(),OrderOpenPrice(),Bid-pt*TrailingStop,OrderTakeProfit(),0,Green);
               }
              }
           }
        if(OrderType()==OP_SELL)  {
         if((OrderOpenPrice()-Ask)>(pt*TrailingStop)){
           if(OrderStopLoss()>(Ask+pt*TrailingStop) || (OrderStopLoss()==0)){
              tiket=OrderModify(OrderTicket(),OrderOpenPrice(),Ask+pt*TrailingStop,OrderTakeProfit(),0,Red);
               }
              }
           }
     }
  
}
void closeall(int m)
{
 for (int i = OrdersTotal() - 1; i >= 0; i--) {
      if(!OrderSelect(i,SELECT_BY_POS,MODE_TRADES))continue;
  if (OrderSymbol() != Symbol() || OrderMagicNumber()!=Magic||  OrderType()!=m) continue;
   if (OrderType() > 1) tiket=OrderDelete(OrderTicket());
  if (OrderType() == 0) tiket=OrderClose(OrderTicket(), OrderLots(), Bid, 3, CLR_NONE);
  if (OrderType() == 1) tiket=OrderClose(OrderTicket(), OrderLots(), Ask, 3, CLR_NONE);
 }
}
double money(int m)
{
 double dp = 0;
 int i;
 for (i = 0; i < OrdersTotal(); i++) {
      if(!OrderSelect(i,SELECT_BY_POS,MODE_TRADES))continue;
  if (OrderSymbol() != Symbol()  || OrderMagicNumber()!=Magic || m!=OrderType()) continue;
  dp += OrderProfit();
 }
 return(dp);
}

void label()
{
 Comment("\n ",
   "\n ",
   "\n ------------------------------------------------",
   "\n :: =>+Jum+Profit<=",
   "\n :: =>JumForex.blogspot.com<=",
   "\n ------------------------------------------------",
   "\n :: Spread                 : ", MarketInfo(Symbol(), MODE_SPREAD),
   "\n :: Leverage               : 1 : ", AccountLeverage(),
   "\n :: Equity                 : ", AccountEquity(),
   "\n :: Jam Server             :", Hour(), ":", Minute(),
   "\n ------------------------------------------------",
   "\n :: Floting buy : ",money(0),
   "\n :: Floting sell : ",money(1),
   "\n ------------------------------------------------",
   "\n :: >>By: Jum69<<",
   "\n ------------------------------------------------");
}

Nah jadi deh
Silahkan simak juga penjelasan disini:

Jangan lupa kasih comment ya !
Pastikan Membaca:

Belajar Membuat EA sederhana part 1

Belajar Membuat EA sederhana part 2

Belajar Membuat EA sederhana part 3

Belajar Membuat EA sederhana part 4

Belajar Membuat EA sederhana part 5

Belajar Membuat EA sederhana part 6

Belajar Membuat EA sederhana part 7

Belajar Membuat EA sederhana part 8

Belajar Membuat EA sederhana part 9

Belajar Membuat EA sederhana part 10

Belajar Membuat EA sederhana part 11

Belajar Membuat EA sederhana part 12

Belajar Membuat EA sederhana part 13

Belajar Membuat EA sederhana part 14

Belajar Membuat EA sederhana part 15

Belajar Membuat EA sederhana part 16

Belajar Membuat EA sederhana part 17

Belajar Membuat EA sederhana part 18

Belajar Membuat EA sederhana part 19

Belajar Membuat EA sederhana part 20

Belajar Membuat EA sederhana part 21

Belajar Membuat EA sederhana part 22

11 komentar untuk "Belajar Membuat EA Sederhana 21 (Jebakan)"

Unknown14 Januari 2013 pukul 14.56
Bang ane sangat tertarik dengan EA abang yg satu ini..
gini bang kalau Pending Ordernya bukan hanya sekali dalam satu hari..
melainkan dapat digunakan berulang-ulang (mis. menggunakan interfal 1 jam)..
perintahnya gimana bang..??
BalasHapus
Balasan
Unknown14 Januari 2013 pukul 15.27
Ooh yah bang,, sekalian mow nanya bisa gak setingan jamnya diganti dengan harga..

misalnya gini..
jika harga berada pada (mis. 1.40000) maka secara otomatis jebakan PO akan berfungsi..
jadi gak berpatokan pada jam lagi bang..
BalasHapus
Balasan
Supriadi20 Januari 2013 pukul 17.56
Komentar ini telah dihapus oleh pengarang.
BalasHapus
Balasan
Supriadi20 Januari 2013 pukul 17.57
saya suka sistem pending ordernya bro. bisa sistemnya seperti ini bro. misalnya kita buka posisi pending order 0.01 sellstop 1.2100 SL 1.2060 TP.1.2040. harga bergerak naik diatas 30 pips, buka lagi posisi baru dgn lot 0.03 dgn TP dan SL harga yg sama tapi di balik. jika harga bergerak lagi dan tdk menyentuh TP dan bergerak turun dan melewati harga buka posisi pertama 15 pips,buka lagi posisi baru dgn lot 0.06 dgn harga TP dan SL seperti semula. jadi kemanapun harga bergerak tetap profit karena kita selalu buka posisi baru dgn kelipatan yang menguntung.
BalasHapus
Balasan
Erlin Herlina29 Juli 2013 pukul 23.30
codingnya jika PO nya tiap 1 jam ( ada candle baru di H1) gimana mas?
kl ditambah marti jika ada PO yg kesentuh namun ga kena tp/floating minus gmn mas?
BalasHapus
Balasan
mohdzzamri10 Januari 2016 pukul 21.18
mas EA yang ini saya copy and paste compile kok erro
BalasHapus
Balasan
Blogger31 Agustus 2017 pukul 02.02
QUANTUM BINARY SIGNALS

Get professional trading signals sent to your mobile phone every day.

Start following our trades today & profit up to 270% daily.
BalasHapus
Balasan
Blogger11 Oktober 2017 pukul 13.55
Imagine if you had a robot with 6 years live proof?

I just got done with a webinar with Mark and his partner, Antony, two days ago and it was GREAT.

During the webinar Mark and Antony shared their secrets to success and answered questions about their new release of the GPS Forex Robot that CAME OUT TODAY!
BalasHapus
Balasan
cah pacitan12 Juli 2020 pukul 20.35
kalao harga tertinggi/terrendah candel sebelumnya apa bahasa programnya bro??
BalasHapus
Balasan

Tambahkan komentar